languages/scss: init

configuration.nix

@@ -60,6 +60,7 @@ isMaximal: {
       clang.enable = isMaximal;
       cmake.enable = isMaximal;
       css.enable = isMaximal;
+      scss.enable = isMaximal;
       html.enable = isMaximal;
       json.enable = isMaximal;
       sql.enable = isMaximal;

docs/manual/release-notes/rl-0.9.md

@@ -104,6 +104,10 @@
 
 - Renamed `languages.ts` to `languages.typescript`.
 
+- Split SCSS from `languages.css` into `languages.scss` and add extra tools for
+  SCSS/SASS. This also changes the default LSP to `some-sass-language-server`
+  for SCSS/SASS.
+
 ## Changelog {#sec-release-0-9-changelog}
 
 [SecBear](https://github.com/SecBear):
@@ -278,6 +282,8 @@
 - Added {option}`vim.lsp.presets.angular-language-server.enable` for Angular
   Template support.
 
+- Added {option}`vim.lsp.presets.some-sass-language-server.enable`.
+
 - Fix `vim.lsp.presets.vala-language-server` to be wrapped correctly with
   `uncrustify`.
 

flake/pkgs/by-name/some-sass-language-server/package.nix

@@ -0,0 +1,70 @@
+# Stolen from <https://github.com/NixOS/nixpkgs/pull/459753>
+# because <nixpkgs> is slower than your mom
+{
+  lib,
+  fetchFromGitHub,
+  buildNpmPackage,
+  pkg-config,
+  libsecret,
+  stdenv,
+}:
+buildNpmPackage (finalAttrs: {
+  pname = "some-sass-language-server";
+  version = "2.3.5";
+
+  src = fetchFromGitHub {
+    owner = "wkillerud";
+    repo = "some-sass";
+    tag = "some-sass-language-server@${finalAttrs.version}";
+    hash = "sha256-rtoHrnMAf3xa1U9vkhPiQ17gsY2yW2knjctod3TbKuo=";
+  };
+
+  npmDepsHash = "sha256-8jKrxqn8jSWUjZURHl53STTD4hcU0Q3iPH9E4r+lKTc=";
+
+  env.PLAYWRIGHT_SKIP_BROWSER_DOWNLOAD = "1";
+  npmInstallFlags = ["--ignore-scripts"];
+
+  nativeBuildInputs = lib.optionals stdenv.isLinux [pkg-config];
+  buildInputs = lib.optionals stdenv.isLinux [libsecret];
+
+  dontNpmBuild = true;
+
+  buildPhase = ''
+    runHook preBuild
+
+    echo "Building vscode-css-languageservice..."
+    npm run build --workspace=packages/vscode-css-languageservice
+
+    echo "Building language-services..."
+    npm run build --workspace=packages/language-services
+
+    echo "Building language-server..."
+    npm run build:production --workspace=packages/language-server
+
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/lib/node_modules/some-sass-language-server
+    cp -r packages/language-server/dist \
+    packages/language-server/bin \
+    packages/language-server/package.json \
+    $out/lib/node_modules/some-sass-language-server/
+
+    mkdir -p $out/bin
+    ln -s $out/lib/node_modules/some-sass-language-server/bin/some-sass-language-server \
+    $out/bin/some-sass-language-server
+
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "Language server with advanced feature support for Scss and Sass files";
+    homepage = "https://wkillerud.github.io/some-sass/";
+    changelog = "https://github.com/wkillerud/some-sass/releases/tag/some-sass-language-server@${finalAttrs.version}";
+    license = lib.licenses.mit;
+    mainProgram = "some-sass-language-server";
+  };
+})

modules/plugins/languages/css.nix

@@ -91,7 +91,6 @@ in {
           filetypes = [
             "css"
             # TODO: split in their own modules
-            "scss"
             "less"
           ];
         });

modules/plugins/languages/default.nix

@@ -13,6 +13,7 @@ in {
     ./clojure.nix
     ./cmake.nix
     ./css.nix
+    ./scss.nix
     ./elixir.nix
     ./elm.nix
     ./fsharp.nix

modules/plugins/languages/scss.nix

@@ -0,0 +1,143 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}: let
+  inherit (builtins) attrNames;
+  inherit (lib.options) mkEnableOption mkOption literalExpression;
+  inherit (lib) genAttrs;
+  inherit (lib.meta) getExe;
+  inherit (lib.modules) mkIf mkMerge;
+  inherit (lib.types) enum listOf;
+  inherit (lib.nvim.types) mkGrammarOption diagnostics;
+  inherit (lib.nvim.attrsets) mapListToAttrs;
+
+  cfg = config.vim.languages.scss;
+
+  defaultServer = ["some-sass-language-server"];
+  servers = ["some-sass-language-server" "vscode-css-language-server"];
+
+  defaultFormat = ["prettier"];
+  formats = {
+    prettier = {
+      command = getExe pkgs.prettier;
+    };
+
+    prettierd = {
+      command = getExe pkgs.prettierd;
+    };
+  };
+
+  defaultDiagnosticsProvider = ["stylelint"];
+  diagnosticsProviders = {
+    stylelint = {
+      config = {
+        cmd = getExe pkgs.stylelint;
+      };
+    };
+  };
+in {
+  options.vim.languages.scss = {
+    enable = mkEnableOption "SCSS/SASS language support";
+
+    treesitter = {
+      enable =
+        mkEnableOption "SCSS/SASS treesitter"
+        // {
+          default = config.vim.languages.enableTreesitter;
+          defaultText = literalExpression "config.vim.languages.enableTreesitter";
+        };
+      package = mkGrammarOption pkgs "scss";
+    };
+
+    lsp = {
+      enable =
+        mkEnableOption "SCSS/SASS LSP support"
+        // {
+          default = config.vim.lsp.enable;
+          defaultText = literalExpression "config.vim.lsp.enable";
+        };
+
+      servers = mkOption {
+        type = listOf (enum servers);
+        default = defaultServer;
+        description = "SCSS/SASS LSP server to use";
+      };
+    };
+
+    format = {
+      enable =
+        mkEnableOption "SCSS/SASS formatting"
+        // {
+          default = config.vim.languages.enableFormat;
+          defaultText = literalExpression "config.vim.languages.enableFormat";
+        };
+      type = mkOption {
+        description = "SCSS/SASS formatter to use";
+        type = listOf (enum (attrNames formats));
+        default = defaultFormat;
+      };
+    };
+
+    extraDiagnostics = {
+      enable =
+        mkEnableOption "extra SCSS/SASS diagnostics"
+        // {
+          default = config.vim.languages.enableExtraDiagnostics;
+          defaultText = literalExpression "config.vim.languages.enableExtraDiagnostics";
+        };
+      types = diagnostics {
+        langDesc = "SCSS";
+        inherit diagnosticsProviders;
+        inherit defaultDiagnosticsProvider;
+      };
+    };
+  };
+
+  config = mkIf cfg.enable (mkMerge [
+    (mkIf cfg.treesitter.enable {
+      vim.treesitter.enable = true;
+      vim.treesitter.grammars = [cfg.treesitter.package];
+    })
+
+    (mkIf cfg.lsp.enable {
+      vim.lsp = {
+        presets = genAttrs cfg.lsp.servers (_: {enable = true;});
+        servers = genAttrs cfg.lsp.servers (_: {
+          filetypes = [
+            "scss"
+            "sass"
+          ];
+        });
+      };
+    })
+
+    (mkIf cfg.format.enable {
+      vim.formatter.conform-nvim = {
+        enable = true;
+        setupOpts = {
+          formatters_by_ft.scss = cfg.format.type;
+          formatters_by_ft.sass = cfg.format.type;
+          formatters =
+            mapListToAttrs (name: {
+              inherit name;
+              value = formats.${name};
+            })
+            cfg.format.type;
+        };
+      };
+    })
+
+    (mkIf cfg.extraDiagnostics.enable {
+      vim.diagnostics.nvim-lint = {
+        enable = true;
+        linters_by_ft.scss = cfg.extraDiagnostics.types;
+        linters_by_ft.sass = cfg.extraDiagnostics.types;
+        linters =
+          mkMerge (map (name: {${name} = diagnosticsProviders.${name}.config;})
+            cfg.extraDiagnostics.types);
+      };
+    })
+  ]);
+}

modules/plugins/lsp/presets/default.nix

@@ -51,6 +51,7 @@
     ./ruff.nix
     ./rumdl.nix
     ./solargraph.nix
+    ./some-sass-language-server.nix
     ./sqls.nix
     ./superhtml.nix
     ./svelte-language-server.nix

modules/plugins/lsp/presets/some-sass-language-server.nix

@@ -0,0 +1,32 @@
+{
+  inputs,
+  config,
+  lib,
+  pkgs,
+  ...
+}: let
+  inherit (lib.meta) getExe;
+  inherit (lib.modules) mkIf;
+  inherit (lib.nvim.types) mkLspPresetEnableOption;
+
+  cfg = config.vim.lsp.presets.some-sass-language-server;
+in {
+  options.vim.lsp.presets.some-sass-language-server = {
+    enable = mkLspPresetEnableOption "some-sass-language-server" "Some Sass" [];
+  };
+
+  config = mkIf cfg.enable {
+    vim.lsp.servers.some-sass-language-server = {
+      enable = true;
+      cmd = [(getExe inputs.self.packages.${pkgs.stdenv.hostPlatform.system}.some-sass-language-server) "--stdio"];
+      root_markers = [".git" "package.json"];
+      # <https://wkillerud.github.io/some-sass/language-server/settings.html>
+      settings = {
+        somesass = {
+          scss.completion.suggestFromUseOnly = true;
+          sass.completion.suggestFromUseOnly = true;
+        };
+      };
+    };
+  };
+}