ConditionalPageBreakForWord/StandardSalesOrderConfReportExt.al at main · miljance/ConditionalPageBreakForWord · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
reportextension 50100 StandardSalesOrderConf extends "Standard Sales - Order Conf."
{
    dataset
    {
        addlast(Line)
        {
            dataitem(PageBreakRepeater; "Integer")
            {
                DataItemTableView = sorting(Number) where(Number = const(1));
                column(EmtpyText; '') { }
                trigger OnPreDataItem()
                begin
                    if not PageBreakAfterLines then
                        CurrReport.Break();
                end;
            }
        }
        addbefore(AssemblyLine)
        {
            dataitem(LineWithoutPageBreak; "Integer")
            {
                DataItemTableView = sorting(Number) where(Number = const(1));
                column(DescriptionWithoutPageBreak; Line.Description) { }
                column(QuantityWithoutPageBreak; FormattedQuantity) { }
                column(UnitOfMeasureWithoutPageBreak; Line."Unit of Measure") { }
                column(UnitPriceWithoutPageBreak; FormattedUnitPrice) { }
                column(LineDiscountPercentTextWithoutPageBreak; LineDiscountPctText) { }
                column(LineAmountWithoutPageBreak; FormattedLineAmount) { }
                column(NoWithoutPageBreak; Line."No.") { }
                column(VATPctWithoutPageBreak; FormattedVATPct) { }
                trigger OnPreDataItem()
                begin
                    if PageBreakBeforeEachLine then
                        CurrReport.Break();
                end;
            }
            dataitem(LineWithPageBreak; "Integer")
            {
                DataItemTableView = sorting(Number) where(Number = const(1));
                column(DescriptionWithPageBreak; Line.Description) { }
                column(QuantityWithPageBreak; FormattedQuantity) { }
                column(UnitOfMeasureWithPageBreak; Line."Unit of Measure") { }
                column(UnitPriceWithPageBreak; FormattedUnitPrice) { }
                column(LineDiscountPercentTextWithPageBreak; LineDiscountPctText) { }
                column(LineAmountWithPageBreak; FormattedLineAmount) { }
                column(NoWithPageBreak; Line."No.") { }
                column(VATPctWithPageBreak; FormattedVATPct) { }
                trigger OnPreDataItem()
                begin
                    if not PageBreakBeforeEachLine then
                        CurrReport.Break();
                end;
            }
        }
    }
    requestpage
    {
        layout
        {
            addlast(Options)
            {
                field(PageBreakBeforeEachLineControl; PageBreakBeforeEachLine)
                {
                    ApplicationArea = All;
                    Caption = 'Page break after each line';
                    ToolTip = 'Page break after each line';
                }
                field(PageBreakAfterLinesControl; PageBreakAfterLines)
                {
                    ApplicationArea = All;
                    Caption = 'Page break after Lines';
                    ToolTip = 'Page break after Lines';
                }
            }
        }

    }
    rendering
    {
        layout("StandardSalesOrderConf.docx")
        {
            Type = Word;
            LayoutFile = './StandardSalesOrderConf.docx';
            Caption = 'Conditional Page Break (Word)';
            Summary = 'Conditional Page Break (Word)';
        }

    }
    var
        PageBreakBeforeEachLine: Boolean;
        PageBreakAfterLines: Boolean;
}